*
*
******************************************************************
**                onsemi Discrete Modeling Group                **
******************************************************************
**                   (C) Copyright 2024 onsemi                  **
**                      All rights reserved                     **
**                                                              **
**                      NVR5198NL Spice model                   **
**                  Revision Rev0.1, 14 Oct 2024                **
******************************************************************
.SUBCKT NVR5198NL  2 1 3      
*Nom Temp=25 deg C   
*External Pin Order and Node Number: Drain(Node 2) - Gate(Node 1) - Source(Node 3)   
Ca 12 8 2.75E-10
Cb 15 14 2.75E-10
Cin 6 8 1.82E-10

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 69.23
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 1.339e-9
Ldrain 2 5 0.3448e-9
Lsource 3 7 1.167e-9

RLgate 1 9 13.39
RLdrain 2 5 3.448
RLsource 3 7 11.67

Mmed 16 6 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD 
Mweak 16 21 8 8 MweakMOD
    
Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 6.894e-2
Rgate 9 20 0.58
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rsource 8 7 RsourceMOD 4.8e-3
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1

S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*14),5))}


.MODEL DbodyMOD D (IS=4.145E-09 N=1.512 RS=2.237e-2 TRS1=1.5e-3 TRS2=0 TT=1.75e-8 XTI=1.9
+ CJO=6.2E-11 M=0.5749)
.MODEL DbreakMOD D (RS=5.6e-1 TRS1=8e-4 TRS2=3e-6)
.MODEL DplcapMOD D (CJO=5E-11 IS=1e-30 M=0.3639)
.MODEL MweakMOD NMOS (VTO=2.05 KP=3.49e-2 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=10) 
.MODEL MmedMOD NMOS (VTO=2.3 KP=1 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=1)
.MODEL MstroMOD NMOS (LEVEL=3 VTO=2.5 KP=5 IS=1e-30 N=10 TOX=1 L=1u W=1u THETA=0.1)


.MODEL RbreakMOD RES (TC1=1.236e-3 TC2=-1.588E-06)
.MODEL RdrainMOD RES (TC1=5.981e-3 TC2=1.883E-05)
.MODEL RSLCMOD RES (TC1=5.4E-3 TC2=1.3E-5)
.MODEL RsourceMOD RES (TC1=3.54e-3 TC2=-7.666E-06)
.MODEL RvthresMOD RES (TC1=-1.6e-3 TC2=-8e-6)
.MODEL RvtempMOD RES (TC1=-3.4e-3 TC2=0)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-6.2 VOFF=-3.1)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-3.1 VOFF=-6.2)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-2.5 VOFF=2)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=2 VOFF=-2.5)

.ENDS NVR5198NL