*$
****************************** IGBT Electrical Parameters ***************************
** Product: FGB20N60SFD_F085
** 600V, 20A Field Stop IGBT
** Model Format: SPICE2G6
**-----------------------------------------------------------------------------------
.SUBCKT FGB20N60SFD_F085 C G E
LE   74 E  0.8431n
RE   83 74 1.08e-3 TC=1.65e-3
RC   85 C  33.1e-3 TC=3.51e-3
RG   G 82  10.15
CGC  82 C  1p 
CGD  92 93 2526p
CGE  E 82  900p
M1   81 82 83 83 MOS W=1u L=1u          
Q1   83 81 85 VPNP 
R1   92 0 1
R2   91 94 1
RLV  95 0 1
DBE  85 81 DE 
DSD  83 81 DO 
DHV  94 93 DR
DLV  94 95 DR 20.25
D1   91 92 DLIM 
D2   94 0  DLIM 
FFB  82 81 VFB 1
VFB  93 0 DC 0  
ESD  96 93 POLY(1) 83 81 19 1
MLV  95 96 93 93 SW           
EGD  91 0 82 81 1
DFRD E C FRD
.MODEL SW NMOS
+ LEVEL=3         VTO=0           KP=5
.MODEL VPNP PNP 
+ IS=3.25e-11     NF=1.5          BF=0.525        CJE=2.0e-9
+ TF=2.59e-10     XTB=3.56        EG=0.62
.MODEL MOS NMOS 
+ LEVEL=3         VMAX=3.0e5      THETA=0.064     ETA=2e-3
+ VTO=6.15        KP=9.4
.MODEL DR D
+ IS=1.0e-14      CJO=1.0e-10     M=0.74          VJ=0.48
.MODEL DO D 
+ IS=1.0e-14      BV=660          CJO=1.02e-9     M=0.56
+ VJ=0.74    
.MODEL DE D
+ IS=1.0e-14      BV=30.0         N=2
.MODEL DLIM D 
+ IS=1.00e-7
.model FRD d
+ IS=5.45e-9      RS=0.0558       EG=1.16         N=1.5
+ ISR=3.15e-10    NR=2.0          TRS1=1.05e-5    TRS2=1.07e-7
+ TT=1.12e-7      BV=660          CJO=8.05e-11    M=0.66
+ VJ=0.75         XTI=0.18        IBV=2.5e-4
.ENDS
*$
******************************* IGBT Thermal Parameters ****************************
** Package: D2-PAK
**----------------------------------------------------------------------------------
.SUBCKT FGB20N60SFD_F085_Thermal TH TL
CTHERM1 TH 6 1.10e-4
CTHERM2 6 5  2.80e-4
CTHERM3 5 4  8.50e-4
CTHERM4 4 3  2.10e-3
CTHERM5 3 2  4.00e-3
CTHERM6 2 TL 8.04e-3
RTHERM1 TH 6 4.60e-4
RTHERM2 6 5  2.40e-3
RTHERM3 5 4  1.28e-2
RTHERM4 4 3  3.04e-2
RTHERM5 3 2  8.50e-2
RTHERM6 2 TL 4.69e-1
.ENDS FGB20N60SFD_F085_Thermal
**----------------------------------------------------------------------------------
** Creation: Dec.-07-2016   Rev.: 1.0
** ON Semiconductor