* Copyright ON Semiconductor 2013
* esd8006mutag PSPice Model Rev.1 – 9/13/2013
****************************************
.options
+ TNOM = 25
+ TEMP = 25
*****************************************
.SUBCKT esd8006mutag 1 2 3 4 5 6 7 8 9 10
X1   1   15  ESDLC3LV_IO1
X2   2   15  ESDLC3LV_IO1
X3   4   15  ESDLC3LV_IO1
X4   5   15  ESDLC3LV_IO1
X5   7   15  ESDLC3LV_IO1
X6   8   15  ESDLC3LV_IO1
R1   15  3   .001
R2   15  6   .001
R3   15  9   .001
R4   15  10  .001
.ENDS
*****************************************
.SUBCKT ESDLC3LV_IO1 1 2
Q1 4 3 1 ESDLC3PNP 
Q2 3 4 5 ESDLC3NPN
D1 6 3 DZ
D2 7 1 DDOWN
RB 4 2 57.0
RC 5 2 0.40
RZ 6 2 4.00
RLEAK 3 2 1500000000
RDBOT 7 2 0.45
CPKG 1 2 40f
.ENDS
******************************************
.MODEL ESDLC3NPN NPN 
+ IS = 20f 
+ BF = 100 
+ IKF = 10 
+ BR = 200 
+ CJE = 3p 
+ TF = 1n 
+ CJC = 3p 
+ NF = 2.1
.MODEL ESDLC3PNP PNP 
+ IS = 1E-12 
+ BF = 1000 
+ IKF = 0.001 
+ ISE = 10p
+ BR = 1000 
+ CJE = 35f 
+ TF = 1n 
+ CJC = 40f
+ NF = 1.0
.MODEL DDOWN D
+ IS = 1E-16
+ N = 1
+ CJO = 32f
+ M = 0
+ VJ = 0.7
+ FC = 0.5
+ TT = 1E-10
+ BV = 45.0 
+ IBV = 1E-6
.MODEL DZ D
+ IS = 1E-18
+ CJO = 5p 
+ N = 1 
+ BV = 6.3
+ IBV = 1E-3