*
*
******************************************************************
**                onsemi Discrete Modeling Group                **
******************************************************************
**         			(C) Copyright 2022 onsemi				    **
**                      All rights reserved                     **
**                                                              **
**                        2V7002W Spice model                   **
**                   Revision Rev0, 29 March 2022               **
******************************************************************
.SUBCKT 2V7002W  2 1 3      
*Nom Temp=25 deg C   
Ca 12 8 1.5E-10
Cb 15 14 1.5E-10
Cin 6 8 2.447E-11

Dbody 7 5 DbodyMOD
Dbreak 5 11 DbreakMOD
Dplcap 10 5 DplcapMOD

Ebreak 11 7 17 18 74.8
Eds 14 8 5 8 1
Egs 13 8 6 8 1
Esg 6 10 6 8 1
Evthres 6 21 19 8 1
Evtemp 20 6 18 22 1

It 8 17 1

Lgate 1 9 1.17e-9
Ldrain 2 5 5.55e-10
Lsource 3 7 9.94e-10

RLgate 1 9 11.7
RLdrain 2 5 5.55
RLsource 3 7 9.94

Mmed 16 6 8 8 MmedMOD
Mstro 16 6 8 8 MstroMOD 
Mweak 16 21 8 8 MweakMOD
    
Rbreak 17 18 RbreakMOD 1
Rdrain 50 16 RdrainMOD 3.04e-3
Rgate 9 20 2.5
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
Rsource 8 7 RsourceMOD 1.215
Rvthres 22 8 RvthresMOD 1
Rvtemp 18 19 RvtempMOD 1

S1a 6 12 13 8 S1AMOD
S1b 13 12 13 8 S1BMOD
S2a 6 15 14 13 S2AMOD
S2b 13 15 14 13 S2BMOD

Vbat 22 19 DC 1

ESLC 51 50  VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*1500),3.5))}


.MODEL DbodyMOD D (IS=4.598E-09 N=1.675 RS=0.109 TRS1=1.358e-3 TRS2=0 TT=6.60e-8 XTI=3.483
+ CJO=8.638E-12 M=0.4682)
.MODEL DbreakMOD D (RS=6.0e-2 TRS1=8e-4 TRS2=3e-6)
.MODEL DplcapMOD D (CJO=4.464E-12 IS=1e-30 M=0.2223)
.MODEL MweakMOD NMOS (VTO=1.732 KP=0.871 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=10) 
.MODEL MmedMOD NMOS (VTO=2.2 KP=5 IS=1e-30 N=10 TOX=1 L=1u W=1u RG=1)
.MODEL MstroMOD NMOS (VTO=2.4 KP=6 IS=1e-30 N=10 TOX=1 L=1u W=1u)


.MODEL RbreakMOD RES (TC1=1.036e-3 TC2=4.839E-08)
.MODEL RdrainMOD RES (TC1=0.9 TC2=4e-3)
.MODEL RSLCMOD RES (TC1=3.2E-3 TC2=3.0E-6)
.MODEL RsourceMOD RES (TC1=2.789e-3 TC2=9.905E-08)
.MODEL RvthresMOD RES (TC1=-1.478e-3 TC2=-7.316E-06)
.MODEL RvtempMOD RES (TC1=-1.893e-3 TC2=-1.249E-06)

.MODEL S1AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-4.0 VOFF=-2.5)
.MODEL S1BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-2.5 VOFF=-4.0)
.MODEL S2AMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=-1 VOFF=0)
.MODEL S2BMOD VSWITCH (RON=1e-5 ROFF=0.1 VON=0 VOFF=-1)

.ENDS 2V7002W